Gecko [ lakemimarlik.com ]

Name	Size	Permission	Date
Algorithm	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
App	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Archive	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Authen	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
CPAN	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Carp	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Config	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Data	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Date	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Digest	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Encode	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Error	[ DIR ]	drwxr-xr-x	2025-07-11 01:02
Exporter	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
ExtUtils	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
File	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Filter	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Getopt	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Git	[ DIR ]	drwxr-xr-x	2025-07-24 02:38
HTML	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
HTTP	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
IO	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
IPC	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
JSON	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
LWP	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Locale	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
MIME	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
MRO	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Math	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Module	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Mozilla	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Net	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Object	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
POD2	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Package	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Params	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Parse	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Perl	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
PerlIO	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Pod	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Software	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Sub	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
TAP	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Term	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Test	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Test2	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Text	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Thread	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Tie	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
Time	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Try	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
Types	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
WWW	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
autodie	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
inc	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
lib	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
libwww	[ DIR ]	drwxr-xr-x	2025-07-11 00:04
local	[ DIR ]	drwxr-xr-x	2025-07-10 23:51
CPAN.pm	144.4 KB	-rw-r--r--	2025-05-14 00:00
Carp.pm	35.12 KB	-rw-r--r--	2018-06-27 14:17
Digest.pm	10.96 KB	-rw-r--r--	2020-10-13 22:59
Env.pm	5.39 KB	-rw-r--r--	2013-03-02 19:10
Error.pm	29.45 KB	-rw-r--r--	2020-01-28 19:51
Expect.pm	98.09 KB	-rw-r--r--	2017-05-18 22:07
Exporter.pm	18.36 KB	-rw-r--r--	2019-11-19 01:21
Fatal.pm	57.7 KB	-rw-r--r--	2021-01-22 20:03
Git.pm	46.87 KB	-rw-r--r--	2025-07-21 19:27
Importer.pm	41.53 KB	-rw-r--r--	2020-08-17 00:24
LWP.pm	21.17 KB	-rw-r--r--	2021-03-07 19:54
Test2.pm	6.24 KB	-rw-r--r--	2020-10-22 06:10
TimeDate.pm	267 B	-rw-r--r--	2020-05-19 20:30
autodie.pm	12.14 KB	-rw-r--r--	2021-01-22 20:03
bigint.pm	22.85 KB	-rw-r--r--	2018-10-09 19:55
bignum.pm	20.64 KB	-rw-r--r--	2018-10-09 19:55
bigrat.pm	15.78 KB	-rw-r--r--	2018-10-09 19:55
constant.pm	14.38 KB	-rw-r--r--	2022-02-16 16:19
experimental.pm	7.39 KB	-rw-r--r--	2020-05-04 23:34
newgetopt.pl	2.15 KB	-rw-r--r--	2010-07-09 15:26
ok.pm	967 B	-rw-r--r--	2020-10-22 06:10
parent.pm	2.64 KB	-rw-r--r--	2020-02-07 10:43
perldoc.pod	9.16 KB	-rw-r--r--	2016-08-02 19:31
perlfaq.pm	77 B	-rw-r--r--	2021-05-20 07:16
perlfaq.pod	22.26 KB	-rw-r--r--	2021-05-20 07:16
perlfaq1.pod	14.09 KB	-rw-r--r--	2021-05-20 07:16
perlfaq2.pod	9.16 KB	-rw-r--r--	2021-05-20 07:16
perlfaq3.pod	36.72 KB	-rw-r--r--	2021-05-20 07:16
perlfaq4.pod	88.69 KB	-rw-r--r--	2021-05-20 07:16
perlfaq5.pod	54 KB	-rw-r--r--	2021-05-20 07:16
perlfaq6.pod	38.61 KB	-rw-r--r--	2021-05-20 07:16
perlfaq7.pod	36.93 KB	-rw-r--r--	2021-05-20 07:16
perlfaq8.pod	48.77 KB	-rw-r--r--	2021-05-20 07:16
perlfaq9.pod	14.86 KB	-rw-r--r--	2021-05-20 07:16
perlglossary.pod	134.02 KB	-rw-r--r--	2021-05-20 07:16
perlxs.pod	82.35 KB	-rw-r--r--	2022-02-16 11:56
perlxstut.pod	48.92 KB	-rw-r--r--	2022-02-16 11:56
perlxstypemap.pod	23.44 KB	-rw-r--r--	2022-02-16 11:56

Rename

package Env;

our $VERSION = '1.04';

=head1 NAME

Env - perl module that imports environment variables as scalars or arrays

=head1 SYNOPSIS

use Env;
    use Env qw(PATH HOME TERM);
    use Env qw($SHELL @LD_LIBRARY_PATH);

=head1 DESCRIPTION

Perl maintains environment variables in a special hash named C<%ENV>.  For
when this access method is inconvenient, the Perl module C<Env> allows
environment variables to be treated as scalar or array variables.

The C<Env::import()> function ties environment variables with suitable
names to global Perl variables with the same names.  By default it
ties all existing environment variables (C<keys %ENV>) to scalars.  If
the C<import> function receives arguments, it takes them to be a list of
variables to tie; it's okay if they don't yet exist. The scalar type
prefix '$' is inferred for any element of this list not prefixed by '$'
or '@'. Arrays are implemented in terms of C<split> and C<join>, using
C<$Config::Config{path_sep}> as the delimiter.

After an environment variable is tied, merely use it like a normal variable.
You may access its value

@path = split(/:/, $PATH);
    print join("\n", @LD_LIBRARY_PATH), "\n";

or modify it

$PATH .= ":.";
    push @LD_LIBRARY_PATH, $dir;

however you'd like. Bear in mind, however, that each access to a tied array
variable requires splitting the environment variable's string anew.

The code:

use Env qw(@PATH);
    push @PATH, '.';

is equivalent to:

use Env qw(PATH);
    $PATH .= ":.";

except that if C<$ENV{PATH}> started out empty, the second approach leaves
it with the (odd) value "C<:.>", but the first approach leaves it with "C<.>".

To remove a tied environment variable from
the environment, assign it the undefined value

undef $PATH;
    undef @LD_LIBRARY_PATH;

=head1 LIMITATIONS

On VMS systems, arrays tied to environment variables are read-only. Attempting
to change anything will cause a warning.

=head1 AUTHOR

Chip Salzenberg E<lt>F<chip@fin.uucp>E<gt>
and
Gregor N. Purdy E<lt>F<gregor@focusresearch.com>E<gt>

=cut

sub import {
    my ($callpack) = caller(0);
    my $pack = shift;
    my @vars = grep /^[\$\@]?[A-Za-z_]\w*$/, (@_ ? @_ : keys(%ENV));
    return unless @vars;

@vars = map { m/^[\$\@]/ ? $_ : '$'.$_ } @vars;

eval "package $callpack; use vars qw(" . join(' ', @vars) . ")";
    die $@ if $@;
    foreach (@vars) {
	my ($type, $name) = m/^([\$\@])(.*)$/;
	if ($type eq '$') {
	    tie ${"${callpack}::$name"}, Env, $name;
	} else {
	    if ($^O eq 'VMS') {
		tie @{"${callpack}::$name"}, Env::Array::VMS, $name;
	    } else {
		tie @{"${callpack}::$name"}, Env::Array, $name;
	    }
	}
    }
}

sub TIESCALAR {
    bless \($_[1]);
}

sub FETCH {
    my ($self) = @_;
    $ENV{$$self};
}

sub STORE {
    my ($self, $value) = @_;
    if (defined($value)) {
	$ENV{$$self} = $value;
    } else {
	delete $ENV{$$self};
    }
}

######################################################################

package Env::Array;
 
use Config;
use Tie::Array;

@ISA = qw(Tie::Array);

my $sep = $Config::Config{path_sep};

sub TIEARRAY {
    bless \($_[1]);
}

sub FETCHSIZE {
    my ($self) = @_;
    return 1 + scalar(() = $ENV{$$self} =~ /\Q$sep\E/g);
}

sub STORESIZE {
    my ($self, $size) = @_;
    my @temp = split($sep, $ENV{$$self});
    $#temp = $size - 1;
    $ENV{$$self} = join($sep, @temp);
}

sub CLEAR {
    my ($self) = @_;
    $ENV{$$self} = '';
}

sub FETCH {
    my ($self, $index) = @_;
    return (split($sep, $ENV{$$self}))[$index];
}

sub STORE {
    my ($self, $index, $value) = @_;
    my @temp = split($sep, $ENV{$$self});
    $temp[$index] = $value;
    $ENV{$$self} = join($sep, @temp);
    return $value;
}

sub EXISTS {
    my ($self, $index) = @_;
    return $index < $self->FETCHSIZE;
}

sub DELETE {
    my ($self, $index) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $value = splice(@temp, $index, 1, ());
    $ENV{$$self} = join($sep, @temp);
    return $value;
}

sub PUSH {
    my $self = shift;
    my @temp = split($sep, $ENV{$$self});
    push @temp, @_;
    $ENV{$$self} = join($sep, @temp);
    return scalar(@temp);
}

sub POP {
    my ($self) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $result = pop @temp;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub UNSHIFT {
    my $self = shift;
    my @temp = split($sep, $ENV{$$self});
    my $result = unshift @temp, @_;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub SHIFT {
    my ($self) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $result = shift @temp;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub SPLICE {
    my $self = shift;
    my $offset = shift;
    my $length = shift;
    my @temp = split($sep, $ENV{$$self});
    if (wantarray) {
	my @result = splice @temp, $offset, $length, @_;
	$ENV{$$self} = join($sep, @temp);
	return @result;
    } else {
	my $result = scalar splice @temp, $offset, $length, @_;
	$ENV{$$self} = join($sep, @temp);
	return $result;
    }
}

######################################################################

package Env::Array::VMS;
use Tie::Array;

@ISA = qw(Tie::Array);
 
sub TIEARRAY {
    bless \($_[1]);
}

sub FETCHSIZE {
    my ($self) = @_;
    my $i = 0;
    while ($i < 127 and defined $ENV{$$self . ';' . $i}) { $i++; };
    return $i;
}

sub FETCH {
    my ($self, $index) = @_;
    return $ENV{$$self . ';' . $index};
}

sub EXISTS {
    my ($self, $index) = @_;
    return $index < $self->FETCHSIZE;
}

sub DELETE { }